Gary Talent
60789230be
976550ef [nostalgia/sample_project] Add missing type descriptors 1fb0a866 [nostalgia/core] Fix CompactPalette TypeName and TypeVersion eb46aeeb [nfde] Fix compiler warnings on Gtk build 9244b735 [nostalgia] Fix non-Linux non-Apple systems not to build GLFW for Wayland 3fba36b4 [nfde] Make only option BUILD_SHARED_LIBS if not already set 6ddb6b42 Merge commit '5461f6700dac79e9e71e3966f8a1270706c385ba' 5461f670 Squashed 'deps/nfde/' changes from 28ade5a5c..5786fabce 1ecc7aa7 Merge commit '26c8cc348eacea01237cd64e1a68d0df8141e848' 26c8cc34 Squashed 'deps/glfw/' changes from 7d5a16ce7..7b6aead9f fc25c12d Merge commit 'ae51a422787bc3b720ff1748c0219c8f33363427' ae51a422 Squashed 'deps/imgui/' changes from f33737806..2db79d086 6c71e1e2 [nostalgia/core/studio,studio] Give TileSheetEditor Ctrl-A and Ctrl-G for selection 2ede01e7 [nostalgia/core/studio] Fix build deacd4ab [nostalgia/core/studio] Fix PaletteEditor add/remove color commands git-subtree-dir: deps/nostalgia git-subtree-split: 976550ef6fa269cf1e367e880f148b0ad7b1b163
58 lines
1.7 KiB
CMake
58 lines
1.7 KiB
CMake
|
|
# NOTE: The order of this list determines the order of items in the Guides
|
|
# (i.e. Pages) list in the generated documentation
|
|
set(source_files
|
|
main.md
|
|
news.md
|
|
quick.md
|
|
moving.md
|
|
compile.md
|
|
build.md
|
|
intro.md
|
|
context.md
|
|
monitor.md
|
|
window.md
|
|
input.md
|
|
vulkan.md
|
|
compat.md
|
|
internal.md)
|
|
|
|
set(extra_files DoxygenLayout.xml header.html footer.html extra.css spaces.svg)
|
|
|
|
set(header_paths
|
|
"${GLFW_SOURCE_DIR}/include/GLFW/glfw3.h"
|
|
"${GLFW_SOURCE_DIR}/include/GLFW/glfw3native.h")
|
|
|
|
# Format the source list into a Doxyfile INPUT value that Doxygen can parse
|
|
foreach(path IN LISTS header_paths)
|
|
string(APPEND GLFW_DOXYGEN_INPUT " \\\n\"${path}\"")
|
|
endforeach()
|
|
foreach(file IN LISTS source_files)
|
|
string(APPEND GLFW_DOXYGEN_INPUT " \\\n\"${CMAKE_CURRENT_SOURCE_DIR}/${file}\"")
|
|
endforeach()
|
|
|
|
set(DOXYGEN_SKIP_DOT TRUE)
|
|
find_package(Doxygen)
|
|
|
|
if (NOT DOXYGEN_FOUND OR DOXYGEN_VERSION VERSION_LESS "1.9.8")
|
|
message(STATUS "Documentation generation requires Doxygen 1.9.8 or later")
|
|
else()
|
|
configure_file(Doxyfile.in Doxyfile @ONLY)
|
|
add_custom_command(OUTPUT "html/index.html"
|
|
COMMAND "${DOXYGEN_EXECUTABLE}"
|
|
WORKING_DIRECTORY "${CMAKE_CURRENT_BINARY_DIR}"
|
|
MAIN_DEPENDENCY Doxyfile
|
|
DEPENDS ${header_paths} ${source_files} ${extra_files}
|
|
COMMENT "Generating HTML documentation"
|
|
VERBATIM)
|
|
|
|
add_custom_target(docs ALL SOURCES "html/index.html")
|
|
set_target_properties(docs PROPERTIES FOLDER "GLFW3")
|
|
|
|
if (GLFW_INSTALL)
|
|
install(DIRECTORY "${GLFW_BINARY_DIR}/docs/html"
|
|
DESTINATION "${CMAKE_INSTALL_DOCDIR}")
|
|
endif()
|
|
endif()
|
|
|